2017年12月13日水曜日

[MT4インジケータ]ちょっと分けて考えてみよう。半分だけのボリンジャーバンド

最近LSMAを研究していて、わりかしいい感じなのですが、その中で、バンドは分けて考えたほうがいいのではないか?ということに気が付きました。
本家のLSMAの方は、二乗平均誤差をベースにあれこれしていますが、メジャーインジケータであるボリンジャーバンドも、分けて考えると違った物が見えてくるかもしれません。

ということで、早速サラッと作ってみました。標準的なボリンジャーバンドの計算方法を移動平均より上のデータと下のデータを分けて計算して描画しています。
データ量が1/2になっっている前提で、バンド幅のσ値を通常の2倍にしています。


わりあい機能するような・・・しないような??
M1とかの逆張りとかのほうがいいのかもしれません。

ソースコードはブログの最後です。

ボリンジャーバンド特有の価格が動いた時に逆方向にもバンド幅が伸びてしまう症状が無いだけでも優秀かもしれません。

せっかく上と下に分けるんだから、high/low見た方がいいかな?ということで、下はlow、上はhighと分けて計算しています。

「MT4でFXを勝ち抜く研究をするブログ」で公開している無料インジケータは、こちらの一覧から。
インジケータ一覧

Twitterもよろしくお願いします。
https://twitter.com/mt4program
Trading View プロフィール

ブログランキングにご協力よろしくお願いします。m(._.)m
にほんブログ村 為替ブログ FX テクニカルトレード派へ
にほんブログ村

お約束ですが、本ブログは、投資に対する利益を約束する物ではありません。最終的には自己責任によるご判断よろしくお願いいたします。

//------------------------------------------------------------------
// +と-側のボリンジャーバンドを別に計算してみた。
#property copyright "Copyright 2017,  Daisuke"
#property link      "http://mt4program.blogspot.jp/"
#property version   "1.00"
#property strict
#property indicator_chart_window

//バッファーを指定する。
#property indicator_buffers 5

//プロット数を指定する。
#property indicator_plots   5

#property indicator_label1  "Band1"
#property indicator_type1   DRAW_LINE
#property indicator_color1  clrAqua
#property indicator_style1  STYLE_SOLID
#property indicator_width1  1

#property indicator_label2  "Band2"
#property indicator_type2   DRAW_LINE
#property indicator_color2  clrAqua
#property indicator_style2  STYLE_DOT
#property indicator_width2  1

#property indicator_label3  "Band3"
#property indicator_type3   DRAW_LINE
#property indicator_color3  clrIndianRed
#property indicator_style3  STYLE_SOLID
#property indicator_width3  1

#property indicator_label4  "Band4"
#property indicator_type4   DRAW_LINE
#property indicator_color4  clrIndianRed
#property indicator_style4  STYLE_SOLID
#property indicator_width4  1

#property indicator_label5  "MA"
#property indicator_type5   DRAW_LINE
#property indicator_color5  clrYellow
#property indicator_style5  STYLE_DOT
#property indicator_width5  2

double m_buffer1[];
double m_buffer2[];
double m_buffer3[];
double m_buffer4[];
double m_buffer5[];

input int MaPeriod = 21;   // 移動平均期間
input ENUM_APPLIED_PRICE PriceMode = PRICE_TYPICAL;   // 対象価格
input double BandWidth1 = 2.0; // バンド幅1
input double BandWidth2 = 4.0; // バンド幅2

//------------------------------------------------------------------
//初期化
int OnInit()
{
   //インジケーターバッファを初期化する。
   SetIndexBuffer(0,m_buffer1);
   SetIndexBuffer(1,m_buffer2);
   SetIndexBuffer(2,m_buffer3);
   SetIndexBuffer(3,m_buffer4);
   SetIndexBuffer(4,m_buffer5);
   
   string short_name = "HBB(" + IntegerToString(MaPeriod) + ")";
   IndicatorShortName(short_name);
   
   return(INIT_SUCCEEDED);
}


//------------------------------------------------------------------
//計算イベント
int OnCalculate(const int rates_total,          //各レート要素数
                const int prev_calculated,      //計算済み要素数
                const datetime &time[],         //要素ごとの時間配列
                const double &open[],           //オープン価格配列
                const double &high[],           //高値配列
                const double &low[],            //安値配列
                const double &close[],          //クローズ価格配列
                const long &tick_volume[],      //ティック数(要素の更新回数)
                const long &volume[],           //実ボリューム(?)
                const int &spread[])            //スプレット
{
   double upDiff[];
   double downDiff[];
   ArrayResize(upDiff, MaPeriod);
   ArrayResize(downDiff, MaPeriod);
   for( int i = rates_total - prev_calculated - 1; i >= 0 && !IsStopped(); i-- )
   {
      if( i > rates_total - MaPeriod ) continue;
      
      m_buffer5[i] = iMA(NULL, PERIOD_CURRENT, MaPeriod, 0, MODE_SMA, PriceMode, i);
      
      ArrayInitialize(upDiff, 0);
      ArrayInitialize(downDiff, 0);
      for( int j = 0; j < MaPeriod; j++ )
      {
         if( high[i + j] > m_buffer5[i + j] ) upDiff[j] = high[i + j] - m_buffer5[i + j];
         if( low[i + j] < m_buffer5[i + j] ) downDiff[j] = m_buffer5[i + j] - low[i + j];
      }
      
      double upStd = StdDev(upDiff, MaPeriod, 0);
      double downStd = StdDev(downDiff, MaPeriod, 0);
      
      m_buffer1[i] = m_buffer5[i] + BandWidth1 * upStd;
      m_buffer2[i] = m_buffer5[i] + BandWidth2 * upStd;
      m_buffer3[i] = m_buffer5[i] - BandWidth1 * downStd;
      m_buffer4[i] = m_buffer5[i] - BandWidth2 * downStd;
   }

   ArrayFree(upDiff);
   ArrayFree(downDiff);

   return rates_total - 1;
}

//------------------------------------------------------------------
//標準偏差を求める。
// return 標準偏差
double StdDev(
   const double &values[],      //元となる配列
   int count,                   //計算対象数
   int shift                    //シフト
)
{
   if( (count + shift) > ArraySize(values) ) return 0;

   double avg = 0 ;
   double mu = 0 ;
   for( int i = shift; i < shift + count; i++ )
   {
      avg += values[i];
   }
   avg = avg / count;

   for( int i = shift; i < shift + count; i++ )
   {
      mu += MathPow(values[i] - avg, 2);
   }

   // 標本標準偏差
   return MathSqrt(mu / (count - 1));
}

2017年12月10日日曜日

[MT4プログラミング]通貨強弱インジをEURベースに変更する。

twitterで質問がありましたので、公開している通貨強弱インジをEURベースに変更する方法です。

通貨強弱インジケータの元ファイルはこちらからもダウンロード可能です。
FX-ONのダウンロードはこちらから。
ダウンロード

ソースコードを修正出来る方ならかんたんに変更可能です。

OnInit関数と、OnCalculate関数内の”USD”と”USDUSD”となっている部分を”EUR”と"EUREUR"に変更するだけです。

なお、後半のCurrencyIndex3/4とCurrencyMultiKairiはこの変更をしてもほとんど表示は変わりません。(USDの線が100から動くやつです。)
システムトラブル等でクロスとドルストレートの間に比率の乖離が起きない限り同じ同じ値となります。これは、最後に通貨間比率の平均で割ってしまっている為です。

■USDを基準に計算した乖離率チャート(上)と、EURを基準にした乖離率チャート(下) (CurrencyMultiKairi)


■USDを基準としたN本前100チャート(上)、EURを基準としたN本前100チャート(下)(CurrencyIndex1)

通貨間の平均で割ったものは相対的な通貨の強弱がはっきり分かる利点があります。USDのラインが動くのが特徴です。しかし、たとえば、USDJPYをトレードしている際、円安になっているのに、他にもっと弱い通貨があって、CurrencyIndex上では円高になっている事もあります。(その場合は逃げ頃なんだと思われますが・・・)

あと、EURをベースにした場合、EURCHFやEURNZDなど、EURをベースとするペアのチャートをある程度過去まで表示しておく必要が有ることにご注意ください。

あ、もしかっこよく改造するのであれば、基準通貨を引数として定義して、パラメータで変更出来る方がいいかもしれません。

サンプルとしてCurrencyIndex1の改造例をブログ最後に乗せておきます。
ナビゲーターからCurrencyIndex1を選択した後、マウス右クリックメニューの修正を選び、赤字の部分を修正してみてください。

※もう少し補足します。
これは私のブログタイトルの付け方が悪かったかもしれません。
CurenncyIndex3,4及びMultiKairiはUSDストレートから計算していますが、最終表示値にはUSD成分は(USD値以外は)含まれていません。

 次の計算を行っています。
・7通貨ペアの対USDインデックス値を計算する。
例EUR/USDインデックス

・8通貨ペア(USDUSDを含む)平均値を簡易USDインデックスとする。
   USDインデックス=100/通貨ペアのインデックス平均値

 ※EURUSDインデックスが101だった場合、EURがUSDに対して基準点か101%になったという意味。EURからみて、USD100/101で99%になった事になる。この場合ドルインデックスは99

・7通貨ペアインデックス値を再度にUSDインデックスを掛け合わせる
 EURインデックス=EUR/USDインデックス ☓ USDインデックス
 EURインデックス=EUR/USDインデックス ☓ (100/通貨ペアの平均値)

ということで、どの通貨を基準に計算しても、ほぼおなじ値となってしまいます。
ほぼというのは、スプレット差などあるので全く同じにはなりません。


その為、各通貨のフローの想定は、線の方向性で見ることになります。
ある2つの通貨の幅が広がっている場合、下方向の通過から上方向の通貨に資金が流れていると想定出来ます。
上記はわかりやすくEUR,USD,JPY,GBPの4通貨のみを表示しています。

JPYが売られてGBPが買われていることがわかるかと思います。
EURも微妙に売られています。EURとJPYだけ比較すると差が広がっていることが分かります。
JPYが売られて、EURも少し売られて、USDとGBPが買われている感じです。

このインジケータは通貨の流通量までは見ていません。例えば、ドル円が1円動くのと、ポンド円が1円動くのとでは、動くお金の量が全く異なります。あくまで価格ベースの参考値となります。
例えば、1ドル=100兆ジンバブエドルになったとしても、1ドル=10兆円なるわけではありません。
しかし、このインジケータの計算方法だと、平均的には50兆倍になった計算になってしまします。

その意味では、このインジケータの初期設定のままだと、GBPに全体が釣られすぎているかもしれません。GBP大暴れです(笑)

そのうち正確性が重要になってきた場合は、2016の取引シェアとかの値を参考に取引量補正も掛けたインジケータを作成したいと思います。

[MT4インジケータ]通貨の強弱をUSDを基準に表示する。その2
[MT4インジケータ]通貨の強弱をUSDを基準に表示する。その3
[MT4インジケータ]通貨の強弱をUSDを基準にその4とFX-ONへのアップロード

「MT4でFXを勝ち抜く研究をするブログ」で公開している無料インジケータは、こちらの一覧から。
インジケータ一覧

Twitterもよろしくお願いします。
https://twitter.com/mt4program
Trading View プロフィール

ブログランキングにご協力よろしくお願いします。m(._.)m
にほんブログ村 為替ブログ FX テクニカルトレード派へ
にほんブログ村

お約束ですが、本ブログは、投資に対する利益を約束する物ではありません。最終的には自己責任によるご判断よろしくお願いいたします。
//------------------------------------------------------------------
// 通貨強弱 インデックス比較インジケータ(N本前開始)
#property copyright "Copyright 2017,  Daisuke"
#property link      "http://mt4program.blogspot.jp/"
#property version   "1.00"
#property strict
#property indicator_separate_window

#include <Arrays/ArrayString.mqh>

//インデックス開始位置タイプ
enum ENUM_INDEX_TYPE
{
   // 固定値
   IDX_TYPE_FIX,
   
   // 前日終値
   IDX_TYPE_DAY,

   // 前週終値
   IDX_TYPE_WEEKEND,

   // 前月終値
   IDX_TYPE_MONTHEND,
};

//バッファーを指定する。
#property indicator_buffers 9

input string sep00 = "";            //【通貨】
input string Currency1 = "EUR";     // 対象通貨1
input color Color1 = clrDodgerBlue; // 対象通貨1色

input string Currency2 = "GBP";     // 対象通貨2
input color Color2 = clrMagenta;    // 対象通貨2色

input string Currency3 = "AUD";     // 対象通貨3
input color Color3 = clrGreen ;     // 対象通貨3色

input string Currency4 = "NZD";     // 対象通貨4
input color Color4 = clrSilver;     // 対象通貨4色

input string Currency5 = "USD";     // 対象通貨5
input color Color5 = clrAqua;       // 対象通貨5色

input string Currency6 = "CAD";     // 対象通貨6
input color Color6 = clrPink;       // 対象通貨6色

input string Currency7 = "CHF";     // 対象通貨7
input color Color7 = clrPaleGreen;  // 対象通貨7色

input string Currency8 = "JPY";     // 対象通貨8
input color Color8 = clrRed;        // 対象通貨8色

input string BaseCurrency = "USD";  // 基準通貨

input string sep10 = "";            //【計算設定】
input ENUM_INDEX_TYPE IndexType = IDX_TYPE_FIX;   // インデックス開始位置タイプ
input int IndexLength = 200;        // インデックス化開始本数(タイプIDX_TYPE_FIX時のみ)
input int MaPeriodBase = 4;         // 比較元移動平均期間(ある程度大きな値でもOK)
input int MaPeriodTarget = 4;       // 比較先移動平均期間(小さい値推奨)

input string sep20 = "";            //【その他】
input string CurrencyPrefix = "";   // 通貨ペア名の前に付く文字列
input string CurrencyPostfix = "";  // 通貨ペア名の後に付く文字列
input int LabelDistance = 3;        // 通貨名ラベル描画スペース

//バッファ
double m_buffer1[];
double m_buffer2[];
double m_buffer3[];
double m_buffer4[];
double m_buffer5[];
double m_buffer6[];
double m_buffer7[];
double m_buffer8[];

//通貨一覧
CArrayString m_currencies;

//通貨ペア一覧
CArrayString m_currencyPairs;

//USDインデックス
int m_usdIndex = -1;

//オブジェクト名
#define OBJECT_NAME "OBJ_CURR_HL"

//色配列
color m_colors[8];

//------------------------------------------------------------------
// 初期化
int OnInit()
{
   ClearObjects();

   IndicatorBuffers(8);

   int count = 0 ;
   SetIndexStyle(count, DRAW_LINE, STYLE_SOLID, 1, Color1);
   SetIndexBuffer(count++, m_buffer1);
   
   SetIndexStyle(count, DRAW_LINE, STYLE_SOLID, 1, Color2);
   SetIndexBuffer(count++, m_buffer2);

   SetIndexStyle(count, DRAW_LINE, STYLE_SOLID, 1, Color3);
   SetIndexBuffer(count++, m_buffer3);

   SetIndexStyle(count, DRAW_LINE, STYLE_SOLID, 1, Color4);
   SetIndexBuffer(count++, m_buffer4);

   SetIndexStyle(count, DRAW_LINE, STYLE_SOLID, 1, Color5);
   SetIndexBuffer(count++, m_buffer5);

   SetIndexStyle(count, DRAW_LINE, STYLE_SOLID, 1, Color6);
   SetIndexBuffer(count++, m_buffer6);

   SetIndexStyle(count, DRAW_LINE, STYLE_SOLID, 1, Color7);
   SetIndexBuffer(count++, m_buffer7);

   SetIndexStyle(count, DRAW_LINE, STYLE_SOLID, 1, Color8);
   SetIndexBuffer(count++, m_buffer8);
   
   m_currencies.Add(Currency1);
   m_currencies.Add(Currency2);
   m_currencies.Add(Currency3);
   m_currencies.Add(Currency4);
   m_currencies.Add(Currency5);
   m_currencies.Add(Currency6);
   m_currencies.Add(Currency7);
   m_currencies.Add(Currency8);
   
   m_colors[0] = Color1;
   m_colors[1] = Color2;
   m_colors[2] = Color3;
   m_colors[3] = Color4;
   m_colors[4] = Color5;
   m_colors[5] = Color6;
   m_colors[6] = Color7;
   m_colors[7] = Color8;

   m_usdIndex = -1;
   for( int i = 0; i < m_currencies.Total(); i++)
   {
      if(m_currencies.At(i) == BaseCurrency)
      {
         m_usdIndex = i;
         break;
      }
   }
   if( m_usdIndex < 0 )
   {
      //USDが見つからない場合、パラメータ異常
      return INIT_PARAMETERS_INCORRECT;
   }

   //USDに対する通貨ペアを生成する。   
   for( int i = 0; i < m_currencies.Total(); i++)
   {
      if( m_currencies.At(i) == "" )
      {
         m_currencyPairs.Add("");
         continue;
      }
      
      if( i < m_usdIndex )
      {
         m_currencyPairs.Add(CurrencyPrefix + m_currencies.At(i) + BaseCurrency + CurrencyPostfix);
      }
      else if( i > m_usdIndex )
      {
         m_currencyPairs.Add(CurrencyPrefix + BaseCurrency + m_currencies.At(i) + CurrencyPostfix);
      }
      else
      {
         m_currencyPairs.Add(BaseCurrency + BaseCurrency);
      }
      //線のラベルを設定する。
      SetIndexLabel(i, m_currencies.At(i));
   }
   
   ChartSetInteger(0, CHART_SHIFT, true);
   ChartSetDouble(0, CHART_SHIFT_SIZE, 12);

   return(INIT_SUCCEEDED);
}

//------------------------------------------------------------------
//終了処理
void OnDeinit( const int reason )
{
   ClearObjects();
}

//------------------------------------------------------------------
//計算イベント
int OnCalculate(
   const int rates_total,          //各レート要素数
 const int prev_calculated,      //計算済み要素数
 const datetime &time[],         //要素ごとの時間配列
 const double &open[],           //オープン価格配列
 const double &high[],           //高値配列
 const double &low[],            //安値配列
 const double &close[],          //クローズ価格配列
 const long &tick_volume[],      //ティック数(要素の更新回数)
 const long &volume[],           //実ボリューム(?)
 const int &spread[])            //スプレット
{
   int total = m_currencyPairs.Total();
   if( IndexType == IDX_TYPE_FIX )
   {
      //新しいバーが生成されたとき。
      if(prev_calculated != rates_total - 1)
      {
         //いったんバッファを初期化する。
         ArrayInitialize(m_buffer1, EMPTY_VALUE);
         ArrayInitialize(m_buffer2, EMPTY_VALUE);
         ArrayInitialize(m_buffer3, EMPTY_VALUE);
         ArrayInitialize(m_buffer4, EMPTY_VALUE);
         ArrayInitialize(m_buffer5, EMPTY_VALUE);
         ArrayInitialize(m_buffer6, EMPTY_VALUE);
         ArrayInitialize(m_buffer7, EMPTY_VALUE);
         ArrayInitialize(m_buffer8, EMPTY_VALUE);
      }
   
      for( int i = IndexLength - 1; i >= 0; i--)
      {
         if( m_buffer1[i] == EMPTY_VALUE || i == 0 )
         {
            for( int j = 0; j < total; j++)
            {
               string pair = m_currencyPairs.At(j);
               if(pair == BaseCurrency + BaseCurrency )
               {
                  SetValue(j, 100, i);
               }
               else
               {
                  double baseValue = iMA(pair, PERIOD_CURRENT, MaPeriodBase, 0, MODE_LWMA, PRICE_CLOSE, IndexLength - 1);
                  double targetValue = iMA(pair, PERIOD_CURRENT, MaPeriodTarget, 0, MODE_LWMA, PRICE_CLOSE, i);
   
                  if( j < m_usdIndex )
                  {
                     if( baseValue != 0 && baseValue != EMPTY_VALUE )
                     {
                        SetValue(j, targetValue / baseValue * 100, i);
                     }
                  }
                  else
                  {
                     if( targetValue != 0 && targetValue != EMPTY_VALUE )
                     {
                        SetValue(j,  baseValue / targetValue * 100, i);
                     }
                  }
               }
            }
         }
      }
   }
   else
   {
      // 特定の区切りをタイミングとする場合
      // 日にち区切りの場合、1時間足以下の必要あり。
      if( IndexType == IDX_TYPE_DAY && Period() > 60 ) return 0;
      // 週区切りの場合、日足以下の必要あり。
      if( IndexType == IDX_TYPE_WEEKEND && Period() > 60 * 24 ) return 0;
      
      //GMT補正とかは考えない・・。
      for( int i = rates_total - prev_calculated - 1; i >= 0; i-- )
      {
         for( int j = 0; j < total; j++)
         {
            string pair = m_currencyPairs.At(j);
            if(pair == BaseCurrency + BaseCurrency )
            {
               SetValue(j, 100, i);
            }
            else
            {
               //おおちゃくw
               //ちゃんと出ない場合は、日足と週足と月足のチャートを一度表示してね。
               //平滑化をかけているのと、終値で判断(始値ではない)のでぴったり100スタートではないので注意。
               double baseValue = 0;
               if( IndexType == IDX_TYPE_DAY )
               {
                  baseValue = iClose( pair, PERIOD_D1, iBarShift(pair, PERIOD_D1, time[i]) + 1);
               }
               else if( IndexType == IDX_TYPE_WEEKEND )
               {
                  baseValue = iClose( pair, PERIOD_W1, iBarShift(pair, PERIOD_W1, time[i]) + 1);
               }
               else if( IndexType == IDX_TYPE_WEEKEND )
               {
                  baseValue = iClose( pair, PERIOD_MN1, iBarShift(pair, PERIOD_MN1, time[i]) + 1);
               }
               double targetValue = iMA(pair, PERIOD_CURRENT, MaPeriodTarget, 0, MODE_LWMA, PRICE_CLOSE, i);

               if( j < m_usdIndex )
               {
                  if( baseValue != 0 && baseValue != EMPTY_VALUE )
                  {
                     SetValue(j, targetValue / baseValue * 100, i);
                  }
               }
               else
               {
                  if( targetValue != 0 && targetValue != EMPTY_VALUE )
                  {
                     SetValue(j,  baseValue / targetValue * 100, i);
                  }
               }
            }
         }
      }      
   }

   
   DrawCurrencyLabels();

   return rates_total - 1;
}


//------------------------------------------------------------------
//通貨ラベルを描画する。
void DrawCurrencyLabels()
{
   //ソート行う。
   //とりあえずバブルソート
   int index[8];
   double rates[8];
   ArrayInitialize(index, 0);
   ArrayInitialize(rates, 0);

   int total = m_currencyPairs.Total();

   for( int i = 0 ; i < total; i++ )
   {
      index[i] = i;
      rates[i] = GetValue(i, 0);
   }
   
   //ソート行う。
   //とりあえずバブルソート
   for( int b = 1 ; b < total; b++ )
   {
      for( int j = 0; j < total - b; j++ )
      {
         if( rates[j] > rates[j + 1]  )
         {
            double work = rates[j + 1];
            rates[j + 1] = rates[j];
            rates[j] = work;
            
            int indexWork = index[j + 1];
            index[j + 1] = index[j];
            index[j] = indexWork;
         }
      }
   }

   //通貨ラベルを更新する。
   ClearObjects();
   int sub = WindowOnDropped();

   double max = ChartGetDouble(0, CHART_PRICE_MAX, sub);
   double min = ChartGetDouble(0, CHART_PRICE_MIN, sub);
   
   double distance = ( max - min ) / (total + 2);
   datetime writeTime = iTime(NULL, PERIOD_CURRENT, 0) + PeriodSeconds() * LabelDistance ;

   for( int j = 0; j < total; j++)
   {
      //描画対象通貨(インデックス)
      int currencyIndex = (int)index[j];
   
      //価格テキストを追加する。
      string objectName = StringFormat("%s_TXT_%d_%d", OBJECT_NAME, sub, j);

      if( ObjectCreate(0, objectName, OBJ_TEXT, WindowOnDropped(),writeTime , min + distance * (j + 1)) )
      {
         // 表示文字列
         ObjectSetString(0, objectName, OBJPROP_TEXT, m_currencies.At(currencyIndex));
         
         // アンカー
         ObjectSetInteger(0, objectName, OBJPROP_ANCHOR, ANCHOR_BOTTOM);
         
         ObjectSetInteger(0, objectName, OBJPROP_COLOR, m_colors[currencyIndex]);
      }
   }
}

//------------------------------------------------------------------
//値を設定する。
void SetValue(
   int i,            //配列番号0~7
   double value,     //値
   int shift)        //シフト
{
   switch(i)
   {
      case 0:
         m_buffer1[shift] = value;
         break;
      case 1:
         m_buffer2[shift] = value;
         break;
      case 2:
         m_buffer3[shift] = value;
         break;
      case 3:
         m_buffer4[shift] = value;
         break;
      case 4:
         m_buffer5[shift] = value;
         break;
      case 5:
         m_buffer6[shift] = value;
         break;
      case 6:
         m_buffer7[shift] = value;
         break;
      case 7:
         m_buffer8[shift] = value;
         break;
   }
}

//------------------------------------------------------------------
//値を取得する。
double GetValue(
   int i,            //配列番号0~7
   int shift)        //シフト
{
   switch(i)
   {
      case 0:
         return m_buffer1[shift];
      case 1:
         return m_buffer2[shift];
      case 2:
         return m_buffer3[shift];
      case 3:
         return m_buffer4[shift];
      case 4:
         return m_buffer5[shift];
      case 5:
         return m_buffer6[shift];
      case 6:
         return m_buffer7[shift];
      case 7:
         return m_buffer8[shift];
   }
   return EMPTY_VALUE;
}

//------------------------------------------------------------------
//オブジェクトをすべて削除する。
void ClearObjects()
{
   long chartId = ChartID();   
   int sub = WindowOnDropped();
   int total = ObjectsTotal( chartId, sub );
   //生成したオブジェクトを削除する。
   //0から削除するとインデックス位置がずれて
   //正しく削除できないため、後ろから削除するようにする。
   for( int i = total - 1; i >= 0 ; i--)
   {
      string name = ObjectName( chartId, i, sub );
      
      // 先頭文字列がRangeRectangleNameと一致する場合、削除する。
      if ( StringFind( name, OBJECT_NAME ) == 0 )
      {
         ObjectDelete( chartId, name );
      }
   }
}