需要があるかどうか、さっぱりわかりませんが、高速版簡易Zigzagです。
MT4にZigzagインジケータついていますが、実は結構遅いです。
ハーモニックパターン検出インジケータの検知にもZigZagのアルゴリズムだけ一部拝借していたのですが、インジケータ再描画時に、消えちゃうパターン対応にするために、全バーに対してZigzag演算していたら処理が返ってきません。
（MT4ですが、いつの間にか3秒以上処理時間がかかると強制的にインジケータをアンロードするような？）
ということで、どうせZigZagは過去の書き換えが発生する前提なので、書き換え範囲を前１頂点に絞り、なるたく高速にそれっぽい情報を描画するインジケータです。
別にZigZagで不満がない人は全く不要なインジケータです。多分EA開発者向け。
ＦＸ－ＯＮにアップロード予定も特にありませんが、ex4ファイルでほしいという方がいらっしゃったら改めて考えます＾＾；；
あ、あと本家のZigZagですが、たまに、頂点間に頂点より大きい別の高値や安値があるのに無視してしまう件だけ対策しています。
共通処理の関数化とかあえて行っていません。なるたけ高速化するためです。
//------------------------------------------------------------------
// 簡易版ZigZag
#property copyright "Copyright 2017, Daisuke"
#property link "http://mt4program.blogspot.jp/"
#property version "1.00"
#property strict
#property indicator_chart_window
#property indicator_buffers 1
#property indicator_label1 "SZG"
#property indicator_type1 DRAW_SECTION
#property indicator_color1 clrRed
#property indicator_style1 STYLE_SOLID
#property indicator_width1 1
input int Depth = 12; // 探査深さ
input int BackStep = 5; // 確定インデックス
//バッファ
double m_zigzag[];
//------------------------------------------------------------------
//初期化
int OnInit()
{
if( Depth < BackStep ) return INIT_PARAMETERS_INCORRECT;
//インジケーターバッファを初期化する。
SetIndexBuffer(0, m_zigzag);
return(INIT_SUCCEEDED);
}
//------------------------------------------------------------------
//計算イベント
int OnCalculate(const int rates_total, //各レート要素数
const int prev_calculated, //計算済み要素数
const datetime &time[], //要素ごとの時間配列
const double &open[], //オープン価格配列
const double &high[], //高値配列
const double &low[], //安値配列
const double &close[], //クローズ価格配列
const long &tick_volume[], //ティック数（要素の更新回数）
const long &volume[], //実ボリューム（？）
const int &spread[]) //スプレット
{
int startIndex = rates_total - prev_calculated - 1;
if( startIndex >= rates_total - Depth )
{
startIndex = rates_total - Depth - 1;
}
// 前頂点の検索
int beforeFlg = 0 ;
int beforeIndex = 0 ;
for( int i = startIndex + BackStep + 1; i < rates_total && beforeFlg == 0 ; i++ )
{
if( m_zigzag[i] != EMPTY_VALUE )
{
if( m_zigzag[i] == high[i] )
{
beforeFlg = 1;
beforeIndex = i;
}
if( m_zigzag[i] == low[i] )
{
beforeFlg = -1;
beforeIndex = i;
}
break;
}
}
for( int i = startIndex; i >= 1; i-- )
{
int backStepIndex = i + BackStep;
m_zigzag[backStepIndex] = EMPTY_VALUE;
int highest = iHighest(NULL, 0, MODE_HIGH, Depth, i);
int lowest = iLowest(NULL, 0, MODE_LOW, Depth, i);
if( highest != lowest )
{
if(lowest == backStepIndex )
{
if( beforeFlg == -1 )
{
if( low[beforeIndex] > low[backStepIndex] )
{
m_zigzag[beforeIndex] = EMPTY_VALUE ;
m_zigzag[backStepIndex] = low[backStepIndex];
beforeFlg = -1;
beforeIndex = backStepIndex;
}
}
else
{
m_zigzag[backStepIndex] = low[backStepIndex];
beforeFlg = -1;
beforeIndex = backStepIndex;
}
}
if( highest == backStepIndex )
{
if( beforeFlg == 1 )
{
if( high[beforeIndex] < high[backStepIndex] )
{
m_zigzag[beforeIndex] = EMPTY_VALUE ;
m_zigzag[backStepIndex] = high[backStepIndex];
beforeFlg = 1;
beforeIndex = backStepIndex;
}
}
else
{
m_zigzag[backStepIndex] = high[backStepIndex];
beforeFlg = 1;
beforeIndex = backStepIndex;
}
}
}
if( highest == lowest && highest == backStepIndex )
{
//同時に発生した場合、
//とりあえず、陽線なら安値、陰線なら高値とする。
if( open[backStepIndex] < close[backStepIndex] )
{
if( beforeFlg == -1 )
{
if( low[beforeIndex] > low[backStepIndex] )
{
m_zigzag[beforeIndex] = EMPTY_VALUE ;
m_zigzag[backStepIndex] = low[backStepIndex];
beforeFlg = -1;
beforeIndex = backStepIndex;
}
}
else
{
m_zigzag[backStepIndex] = low[backStepIndex];
beforeFlg = -1;
beforeIndex = backStepIndex;
}
}
else
{
if( beforeFlg == 1 )
{
if( high[beforeIndex] < high[backStepIndex] )
{
m_zigzag[beforeIndex] = EMPTY_VALUE ;
m_zigzag[backStepIndex] = high[backStepIndex];
beforeFlg = 1;
beforeIndex = backStepIndex;
}
}
else
{
m_zigzag[backStepIndex] = high[backStepIndex];
beforeFlg = 1;
beforeIndex = backStepIndex;
}
}
}
}
return rates_total - 1;
}
「MT4でFXを勝ち抜く研究をするブログ」で公開している無料インジケータは、こちらの一覧から。
インジケータ一覧Twitterもよろしくお願いします。
https://twitter.com/mt4program
ブログランキングにご協力よろしくお願いします。m(._.)m
 にほんブログ村 |
 |
お約束ですが、本ブログは、投資に対する利益を約束する物ではありません。最終的には自己責任によるご判断よろしくお願いいたします。
